Of late I’ve been studying light, and thought it would be fun to write a program to model light striking a planar mirror. I have now got a working version out which happily traces the rays using some simple vector math and a slightly buggy ray tracing algorithm. Pictures are necessary :D

## Archive for the ‘**Code**’ Tag

## Simple 2D Ray Tracer Leave a comment

## SICP Section 2.3.4 Leave a comment

## SICP Section 2.3.3 Leave a comment

## More pong updates Leave a comment

My Curses based pong clone is coming along rather nicely, I’ve made many improvements to the codebase, and also added a proper interface.

Changes:

- Added menu system
- Added “fancy” background in the menu
- Added proper build system
- Added the ability to customize the size of the playing field
- Tidied up the code
- Messed it up a bit more :D

It’s been a very educational experience working with ncurses and C, which are both very new to me, but I’m getting better at interpreting gcc’s error messages… often 10 lines of error can be generated by something as simple as a missed closing bracket! I also finally got around to writing a makefile for the project, which simplifies the task of building it quite a lot. `make debug`

is all I need to get debuggable code ready.

That’s all for now, I plan to post something on the actual game mechanics sometime soon, as always, you can enjoy the game by grabbing it from github

## The Rest Period and Pong 2 comments

Wow, haven’t posted in a while, but rest assured, I’ve been pretty busy! I’ve had a bunch of tests and exams recently in school, so I’ve had less time to work on things digital, but I’ve still managed to accomplish a fair bit.

I’m still working through SICP, I’m working on the part about data structures for sets.

I have done a total rewrite of my NCurses PONG Clone, and present to you the result:

I’ve got AI, a scoreboard and a few other things which I’m currently working on, check out the code at github

## pyafg – new features! Leave a comment

If you’ve been watching my pyafg github repo of late, you will have noticed that I’ve been very busy hacking on pyafg in the last few weeks, and have managed to add a heap of cool new features.

**What’s New**

- Added a graphical transform editor
- Added a gradient coloring system
- Added more features!
- Added some more fractals
- Fixed many bugs
- Made the pygame interface cleaner
- You can now save images in the pygame interface
- Added gradient demo

The transform editor was written using tkinter, and so for that reason it is neither pretty nor quick (for some reason tkinter does not support drawing directly to a canvas, you have to make objects on the canvas), but it does the job well, and I’ve managed to create quite a few neat looking fractals with it. In the future I hope to make a gtk or qt interface, but until then, it should do the job.

I’ll need to tidy up and standardize the command line arguments to pyafg, because I’ve added a lot more options. Here is an example of gradient coloring.

Here is a shot of the gradient for the above image.

## SICP – Section 2.3.1-2.3.2 Leave a comment

This section introduces the idea of “symbolic data”, and demonstrates how we can abstract our code with it. I found it to be really enjoyable, the questions were very challenging at the end. I notice I seem to say that I find each section enjoyable, and I do! I cannot recommend this book enough, not only for the knowledge and ideas you gain from it, but for the fun you’ll have solving the problems.

**;;Exercise 2.53**

As usual, just a check to make sure we understand how to manipulate symbolic data.

`>(list '(a b c))`

(a b c)

>(list (list 'george))

*((george))*

>(cdr '((x1 x2) (y1 y2)))

*(y1 y2)*

>(cadr '((x1 x2) (y1 y2)))

*y1*

>(pair? (car '(a short list)))

*#f*

>(memq 'red '((red shoes) (blue socks)))

*#f*

>(memq 'red '(red shoes blue socks))

*(red shoes blue socks) *

**;;Exercise 2.54**

A fairly straightforward implementation of the recursive description they gave.

```
(define (my-equal? a b)
(cond ((and (eq? a '()) (eq? b '())) true)
((and (symbol? a) (symbol? b))
(eq? a b))
((and (pair? a) (pair? b))
(and (my-equal? (car a) (car b))
(my-equal? (cdr a) (cdr b))))
(else false)))
```

**;;Exercise 2.55**

The first challenging question. Had me stumped for a while, even when I typed the code in at my interpreter I didn’t get it, however, if you notice the footnote no. 34, it explains that the interpreter replaces each use of `'`

with a `quote`

. So `''abracadabra`

is `'(quote abracadabra)`

, and the car of that list is the symbol `quote`

!

**;;Exercise 2.56**

We’ve been introduced to the differentiation program, a very nice example of abstraction. The key to this exercise is pretty much to copy what happens for the other rules, just supplying different selectors and constructors, and a bit more code in the deriv function. I’m a bit of a rebel ;) I chose to use the ‘^ symbol instead of ‘**, as ‘^ seems more intuitive to me :)

Here are the selectors, predicate, and constructors:

```
;;'(^ b a)
(define (exponentiation? x)
(and (pair? x) (eq? (car x) '^)))
(define (base x)
(cadr x))
(define (exponent x)
(caddr x))
(define (make-exponentiation base exponent)
(cond ((and (number? base) (number? exponent))
(expt base exponent))
((=number? exponent 0) 1)
((=number? exponent 1) base)
(else (list '^ base exponent))))
```

And here is the modified deriv function:

```
(define (deriv expr var)
(cond ((number? expr) 0)
((variable? expr)
(if (same-variable? expr var) 1 0))
((exponentiation? expr) ;;EXPONENTIATION RULE
(make-product
(make-product (exponent expr)
(make-exponentiation (base expr)
(- (exponent expr) 1)))
(deriv (base expr) var)))
((sum? expr)
(make-sum (deriv (addend expr) var)
(deriv (augend expr) var)))
((product? expr)
(make-sum
(make-product (multiplier expr)
(deriv (multiplicand expr) var))
(make-product (deriv (multiplier expr) var)
(multiplicand expr))))
(else
(error "unknown expression type -- DERIV" expr))))
```

And a test,

`>(deriv '(^ x 4) 'x)`

*(* 4 (^ x 3))*

**;;Exercise 2.57**

I had some initial difficulties with this question, I understood what I was attempting to do in the selectors, but the constructors were a little trickier. With the selectors, the only interesting bit is in the augend selector. When we get the augend, we must remember if there is a list, we need to return it as the sum of the rest of the items in the list, not a a list of two or more numbers. eg. (augend ‘(+ 1 2 3)) is (+ 2 3) not (2 3).

```
(define (addend s) (cadr s))
(define (augend s)
(let ((aug (cddr s)))
(if (eq? (cdr aug) '())
(car aug)
(make-sum (car aug)
(cdr aug)))))
```

The constructor also held me up for a little while, as I had a bit of a hiccup in my code.

I was not combining the augend a2 into the list (‘+ a1 a2) correctly. This is best shown with some code…

`>(make-sum x (2 (* 5 y)))`

*(+ x (2 (* 5 y)))*

As you can see, instead of combining the 2 at the same level as x, it is a separate list, (2 (* 5 y)) which the program does not know how to parse. It should of course be (+ x 2 (* 5 y)). How do we combine the lists? Using append! Here is the constructor then:

```
(define (make-sum a1 a2)
(cond ((=number? a1 0) a2)
((=number? a2 0) a1)
((and (number? a1) (number? a2)) (+ a1 a2))
(else (append (list '+ a1) a2))))
```

Note that we can leave all the simplification code in, it will still work even in the new format. The changes to product are almost exactly the same as the changes to sum, I feel as though there’s an underlying abstraction somewhere ;)

Here’s the full code, including the product as well as sum, remember that this is all available on my sicp github repo.

```
;;(+ x y z)
(define (addend s) (cadr s))
(define (augend s)
(let ((aug (cddr s)))
(if (eq? (cdr aug) '())
(car aug)
(make-sum (car aug)
(cdr aug)))))
(define (make-sum a1 a2)
(cond ((=number? a1 0) a2)
((=number? a2 0) a1)
((and (number? a1) (number? a2)) (+ a1 a2))
(else (append (list '+ a1) a2))))
;;'(* x y z)
(define (multiplier p) (cadr p))
(define (multiplicand p)
(let ((mult (cddr p)))
(if (eq? (cdr mult) '())
(car mult)
(make-product (car mult)
(cdr mult)))))
(define (make-product m1 m2)
(cond ((or (=number? m1 0) (=number? m2 0)) 0)
((=number? m1 1) m2)
((=number? m2 1) m1)
((and (number? m1) (number? m2)) (* m1 m2))
(else (append (list '* m1) m2))))
```

**;;Exercise 2.58**

**;;Part A**

Things are getting interesting, we are now getting out of the safe world of polish notation, and into the rather complex one of parsing infix expressions. However, part a is very easy to implement, it simply requires swapping the parsing of* *the operator and the first operand, the change is exactly the same for multiplication.

```
(define (sum? x)
(and (pair? x) (eq? (cadr x) '+)))
(define (addend s) (car s))
(define (augend s) (caddr s))
(define (make-sum a1 a2)
(cond ((=number? a1 0) a2)
((=number? a2 0) a1)
((and (number? a1) (number? a2)) (+ a1 a2))
(else (list a1 '+ a2))))
```

**;;Part B**

Part b is simply put, a beast of a question. It most certainly is quite a difficult problem, but it’s definitely possible! In fact, I suggest you stop reading now, so that you can have the same exhiliration that I got upon solving it! We are now required to parse infix expressions with any or no parenthization. I mulled over this one for a couple days, and spent more than a few nights writing attempts to solve it in my note book. I finally hit epiphany at badminton on Thursday (6/5/10) night.

Before we do anything, we should state what we are attempting to accomplish with our code. This is a bit trickier than it sounds, so let’s go through a couple examples and see if we can find anything interesting.

`(x * (6 + y) + 5)`

is equivalent to

`((x * (6 + y)) + 5)`

(note the extra parenthesis before *x*)

So one thing we need to do is replace parentheses to make it easier to parse.

`(x * (6 + y) + 5)`

can be reduced like so:

```
addend: x * (6 + y)
multiplier: x
multiplicand: (6 + y)
addend: 6
augend: y
augend:
```

This looks like a job for recursion to me, and it also looks like we’ll need to worry about putting sums in the right place before the products. For example, if we tried to grab the multiplicand of (3 * 6 + 5) we would obtain 6 + 5 instead of 6.

We can come up with a simple recursive definition for this:

If the augend of *expr* is a *sum*, then the augend of *expr* is the *sum* of everything after the *sum* operator in *expr* (y + 3* z). If the augend of *expr* is a *product*, then the augend of *expr* is the *product* of everything after the *product* operator in *expr*. If the augend of *expr* is a single *variable* then the augend of *expr* is the first item after the *sum* operator. Finally if the augend of *expr* is a single *number*, then the augend of *expr* is the first item after the *sum* operator.

So we can see that there are four rules to apply here which will eventually filter down to the base case of the single variable or number. So, the first thing we will implement is the definition of a sum and product. An expression is a sum if it has the ‘+ operator in it, and an expression is a product if it has only the ‘* operator in it. This gives us the proper operator precedence. The in? predicate here tells whether a given symbol is in a list.

```
(define (sum? x)
(and (pair? x) (in? '+ x)))
(define (product? x)
(and (pair? x) (not (in? '+ x)) (in? '* x)))
```

Now that we have our definitions of what constitutes a sum, we need to give the definitions of addend and augend. The addend is everything before the first ‘+ operator, but we also need to process the addend (remember the recursive definition) to correctly resolve operator precedence in it. We will do this with the recursive process stated above as a procedure named *process-expr* which I will leave unspecified. Remember that black box abstraction, and wishful thinking are very important. Anyway, here’s the definition of addend and augend, *split-on* is a function which gives a cons where the car is everything before the symbol, and the cdr is everything after the symbol.

`>(split-on '+ (1* x + 2 * y))`

*((1 * x) 2 y)*

```
(define (addend s)
(process-expr (car (split-on '+ s))))
(define (augend s)
(process-expr (cdr (split-on '+ s))))
```

Now it’s almost all in place, there’s one more definition left, how do we construct a sum? This is very easy, and stays the same as what we implemented for part A, `(list a1 '+ a2).`

Now, to implement the *process-expr* procedure. Since we have already defined all the selectors and constructors, this will be very easy.

```
(define (process-expr expr)
(cond ((if (= (length expr) 1) (variable? (car expr)) false) (car expr))
((if (= (length expr) 1) (number? (car expr)) false) (car expr))
((sum? expr) (make-sum (addend expr)
(augend expr)))
((product? expr) (make-product (multiplier expr)
(multiplicand expr))))))
```

This is a beautiful example of mutual recursion, and the great thing is, that it works! I first wrote this while waiting to play at badminton, and when I tranferred it from paper, it worked first try, with just a couple hiccups. One of those hiccups was the parsing of a parenthized expression such as `(3 * (5 + 4))`

. The augend of this expression is ((5 + 4)), which is (list (list 5 + 4)). When process-expr encounters this, it checks if it is a variable, but while the length of (list (list 5 ‘+ 4)) is 1, it will not satisfy either the variable? or the number? predicate. It will then check if it is a sum, but there is no ‘+ in (list (list 5 + 4)), and it will also check if it is a product, but it won’t satisfy that either, so the cond expression will return #void! This is a bit of a bug, but it is fairly easy to fix. Let’s think of a parenthized-expression as another type of expression. It must satisfy these requirements to be considered parethized:

- Must have a length of 1
- Must not be a variable
- Must not be a number
- It’s car must be either a sum or a product

This is readily expressed as a procedure.

```
(define (parenthized-expression? expr)
(and (not (variable? expr))
(not (number? expr))
(= (length expr) 1)
(or (sum? (car expr))
(product? (car expr)))))
;;Selector
(define (deparenthize expr) (car expr))
```

Now, we just need to add a rule for handling parenthized-expressions to *process-expr*. This is accomplished by adding a *let* expression, which will bind *expr* correctly:

```
(define (process-expr expr)
(let ((expr (if (parenthized-expression? expr) (deparenthize expr) expr)))
(cond ((if (= (length expr) 1) (variable? (car expr)) false) (car expr))
((if (= (length expr) 1) (number? (car expr)) false) (car expr))
((sum? expr) (make-sum (addend expr)
(augend expr)))
((product? expr) (make-product (multiplier expr)
(multiplicand expr))))))
```

We’re done! We have now created a fairly useful symbolic differentiator, which can handle (almost) arbitrary expressions. There is nothing as exhilirating as solving a really tough problem, and this can definitely be ranked as one of them! Here is all the code, and remember, this code is on my sicp github repo.

*Happy Hacking!*
;;Split an expr on symb
(define (split-on symb expr)
(define (iter r l)
(cond ((eq? l '()) r)
((eq? symb (car l)) (cons r (cdr l)))
(else (iter (append r (list (car l))) (cdr l)))))
(iter '() expr))
;;Is symb in expr?
(define (in? symb expr)
(cond ((eq? expr '()) false)
((eq? symb (car expr)) true)
(else (in? symb (cdr expr)))))
;; representing algebraic expressions
(define (variable? x) (symbol? x))
(define (same-variable? v1 v2)
(and (variable? v1) (variable? v2) (eq? v1 v2)))
(define (=number? exp num)
(and (number? exp) (= exp num)))
;;Is expr a parenthized expression? eg. ((1 + 2))
(define (parenthized-expression? expr)
(and (not (variable? expr))
(not (number? expr))
(= (length expr) 1)
(or (sum? (car expr))
(product? (car expr)))))
(define (process-expr expr)
(let ((expr (if (parenthized-expression? expr) (deparenthize expr) expr)))
(cond ((if (= (length expr) 1) (variable? (car expr)) false) (car expr))
((if (= (length expr) 1) (number? (car expr)) false) (car expr))
((sum? expr) (make-sum (addend expr)
(augend expr)))
((product? expr) (make-product (multiplier expr)
(multiplicand expr))))))
(define (deparenthize expr) (car expr))
;;'(+ x y)
(define (sum? x)
(and (pair? x) (in? '+ x)))
(define (addend s)
(process-expr (car (split-on '+ s))))
(define (augend s)
(process-expr (cdr (split-on '+ s))))
(define (make-sum a1 a2)
(cond ((=number? a1 0) a2)
((=number? a2 0) a1)
((and (number? a1) (number? a2)) (+ a1 a2))
(else (list a1 '+ a2))))
;;'(* x y)
(define (product? x)
(and (pair? x) (not (in? '+ x)) (in? '* x)))
(define (multiplier p)
(process-expr (car (split-on '* p))))
(define (multiplicand p)
(process-expr (cdr (split-on '* p))))
(define (make-product m1 m2)
(cond ((or (=number? m1 0) (=number? m2 0)) 0)
((=number? m1 1) m2)
((=number? m2 1) m1)
((and (number? m1) (number? m2)) (* m1 m2))
(else (list m1 '* m2))))
(define (deriv expr var)
(cond ((number? expr) 0)
((variable? expr)
(if (same-variable? expr var) 1 0))
((sum? expr)
(make-sum (deriv (addend expr) var)
(deriv (augend expr) var)))
((product? expr)
(make-sum
(make-product (multiplier expr)
(deriv (multiplicand expr) var))
(make-product (deriv (multiplier expr) var)
(multiplicand expr))))
(else
(error "unknown expression type -- DERIV" expr))))

`>(deriv '(x + 3 * (x + y + 2)) 'x)`

*4*